;    PostgreSQL for Windows by Mohawk Software
;    Copyright (C) 2002-2003 Mark L. Woodward
; 
;    This file is free software; you can redistribute it and/or
;    modify it under the terms of the GNU General Public
;    License as published by the Free Software Foundation; either
;    version 2 of the License, or (at your option) any later version.
; 
;    This file is distributed in the hope that it will be useful,
;    but WITHOUT ANY WARRANTY; without even the implied warranty of
;    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
;    Library General Public License for more details.
; 
;    You should have received a copy of the GNU General Public
;    License along with this file; if not, write to the Free
;    Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
;    MA 02111-1307, USA
; 
;    If you want support or to commercially license this file, the author
;    can be reached at sales@mohawksoft.com

[Setup]
AppName=PostgreSQL 
AppVerName=PostgreSQL 7.3 for Windows
AppPublisher=Mohawk Software
AppPublisherURL=http://www.mohawksoft.com
AppSupportURL=http://www.mohawksoft.com
AppUpdatesURL=http://www.mohawksoft.com
DefaultDirName={sd}\PostgreSQL
DisableStartupPrompt=yes
DefaultGroupName=PostgreSQL 
AllowNoIcons=yes
SourceDir=e:\pginstall\source
OutputBaseFilename=pgsetup
OutputDir=e:\pginstall\PostgreSQL

[Registry]
Root: HKLM; Subkey: "SOFTWARE\Cygnus Solutions"; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "SOFTWARE\Cygnus Solutions\Cygwin"; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "SOFTWARE\Cygnus Solutions\Cygwin\mounts v2"; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "SOFTWARE\Cygnus Solutions\Cygwin\mounts v2"; ValueType: String; ValueName: "cygdrive prefix"; ValueData: "/disks"; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "SOFTWARE\Cygnus Solutions\Cygwin\mounts v2"; ValueType: dword; ValueName: "cygdrive flags"; ValueData: "34"; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "SOFTWARE\Cygnus Solutions\Cygwin\mounts v2\/"; ValueType: String; ValueName: "native"; ValueData: "{app}"; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "SOFTWARE\Cygnus Solutions\Cygwin\mounts v2\/"; ValueType: dword; ValueName: "flags"; ValueData: "$0A"; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "SOFTWARE\Cygnus Solutions\Cygwin\mounts v2\/usr/bin"; ValueType: String; ValueName: "native"; ValueData: "{app}/bin"; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "SOFTWARE\Cygnus Solutions\Cygwin\mounts v2\/usr/bin"; ValueType: dword; ValueName: "flags"; ValueData: "$0A"; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "SOFTWARE\Cygnus Solutions\Cygwin\mounts v2\/usr/lib"; ValueType: String; ValueName: "native"; ValueData: "{app}/lib"; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "SOFTWARE\Cygnus Solutions\Cygwin\mounts v2\/usr/lib"; ValueType: dword; ValueName: "flags"; ValueData: "$0A"; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "SOFTWARE\Cygnus Solutions\Cygwin\mounts v2\/usr/X11R6/lib/X11/fonts"; ValueType: String; ValueName: "native"; ValueData: "{app}\\usr\\X11R6\\lib\\X11\\fonts"; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "SOFTWARE\Cygnus Solutions\Cygwin\mounts v2\/usr/X11R6/lib/X11/fonts"; ValueType: dword; ValueName: "flags"; ValueData: "$0A"; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "SOFTWARE\Cygnus Solutions\Cygwin\Program Options"; Flags: uninsdeletekeyifempty

; Registry entries for PostgreSQL Server Console
Root: HKLM; Subkey: "Software\CygConsole"; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "Software\CygConsole\PostgreSQL"; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "Software\CygConsole\PostgreSQL"; ValueType: String; ValueName: "command"; ValueData: "{app}/bin/bash --login -c ""postmaster -D /data"" "; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "Software\CygConsole\PostgreSQL"; ValueType: String; ValueName: "prerun"; ValueData: "{app}/bin/ipc-daemon.exe"; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "Software\CygConsole\PostgreSQL"; ValueType: String; ValueName: "kill"; ValueData: "{app}/bin/kill.exe"; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "Software\CygConsole\PostgreSQL"; ValueType: String; ValueName: "pidfile"; ValueData: "{app}/data/postmaster.pid"; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "Software\CygConsole\PostgreSQL"; ValueType: String; ValueName: "bindir"; ValueData: "{app}/bin"; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "Software\CygConsole\PostgreSQL"; ValueType: String; ValueName: "logfile"; ValueData: "{app}\postgresql.log"; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "Software\CygConsole\PostgreSQL"; ValueType: String; ValueName: "logout"; ValueData: "TRUE"; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "Software\CygConsole\PostgreSQL"; ValueType: String; ValueName: "title"; ValueData: "PostgreSQL Server"; Flags: uninsdeletekeyifempty

; Registry entries for pgsetup
Root: HKLM; Subkey: "Software\CygConsole\pgsetup"; ValueType: String; ValueName: "command"; ValueData: "{app}/bin/bash --login -c ""pgsetup.sh {username}"" "; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "Software\CygConsole\pgsetup"; ValueType: String; ValueName: "prerun"; ValueData: "{app}/bin/ipc-daemon.exe"; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "Software\CygConsole\pgsetup"; ValueType: String; ValueName: "kill"; ValueData: ""; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "Software\CygConsole\pgsetup"; ValueType: String; ValueName: "pidfile"; ValueData: ""; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "Software\CygConsole\pgsetup"; ValueType: String; ValueName: "bindir"; ValueData: "{app}/bin"; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "Software\CygConsole\pgsetup"; ValueType: String; ValueName: "title"; ValueData: "Creating Database Environment"; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "Software\CygConsole\pgsetup"; ValueType: String; ValueName: "stopquit"; ValueData: "TRUE"; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "Software\CygConsole\pgsetup"; ValueType: String; ValueName: "shutdown"; ValueData: "PostgreSQL Shutdown"; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "Software\CygConsole\pgsetup"; ValueType: String; ValueName: "logfile"; ValueData: "{app}\setup.log"; Flags: uninsdeletekeyifempty
Root: HKLM; Subkey: "Software\CygConsole\pgsetup"; ValueType: String; ValueName: "logout"; ValueData: "TRUE"; Flags: uninsdeletekeyifempty


[Components]
Name: pgsql; Description: "Install PostgreSQL Database Environment"; types: full compact custom; ExtraDiskSpaceRequired: 32657356
Name: initdb; Description: "Create initial database (This is required to use PostgreSQL)";  types: full compact custom ; ExtraDiskSpaceRequired: 24478715;
Name: unix; Description: "Text Console Administration Tools (For Power Users)"; ExtraDiskSpaceRequired: 1024; types: full compact;


[Tasks]
Name: lowperf; Description: "Light performance (Uses less memory)"; GroupDescription: "Performance"; Components: pgsql; Flags: exclusive unchecked ;
Name: userperf; Description: "Standard performance"; GroupDescription: "Performance";   Flags: exclusive  ; Components: pgsql
Name: highperf; Description: "High performance (Uses more memory)";  GroupDescription: "Performance";  Flags: exclusive unchecked  ; Components: pgsql
Name: open; Description: "No Network Security (All clients can connect)"; GroupDescription: "Network Security";  Flags: exclusive unchecked ; Components: pgsql
Name: user; Description: "Only local users can access database"; GroupDescription: "Network Security";  Flags: exclusive  ; Components: pgsql
Name: closed; Description: "Very secure (User must configure system)"; GroupDescription: "Network Security";  Flags: exclusive unchecked ; Components: pgsql
Name: startmenu; Description: "Put PostgreSQL in Startup Folder"; GroupDescription: "Startup Options"; Components: pgsql;Flags: exclusive unchecked ;

[Files]
Source: "PostgreSQL\*.*"; DestDir: "{app}"; CopyMode: alwaysoverwrite;  Flags: recursesubdirs; Components: pgsql
Source: "cygconsole.exe"; DestDir: "{app}\bin"; CopyMode: alwaysoverwrite ; Components: pgsql
Source: "pgsetup.sh"; DestDir: "{app}\bin"; CopyMode: alwaysoverwrite; Components: pgsql
Source: "pgsql.bat"; DestDir: "{app}\bin"; CopyMode: alwaysoverwrite; Components: pgsql
Source: "pgshell.bat"; DestDir: "{app}\bin"; CopyMode: alwaysoverwrite; Components: pgsql
Source: "profile"; DestDir: "{app}\etc"; CopyMode: alwaysoverwrite; Components: pgsql

; Choose which postgresql.conf.sample to install
Source: "postgresql.conf.highperf"; DestDir: "{app}/usr/share/postgresql"; DestName: postgresql.conf.sample; Tasks: highperf  ; Components: pgsql
Source: "postgresql.conf.user"; DestDir: "{app}/usr/share/postgresql"; DestName: postgresql.conf.sample; Tasks: userperf ; Components: pgsql
Source: "postgresql.conf.sample"; DestDir: "{app}/usr/share/postgresql"; DestName: postgresql.conf.sample; Tasks: lowperf ; Components: pgsql
; Choose which pg_hba.conf.sample to install
Source: "pg_hba.conf.user"; DestDir: "{app}/usr/share/postgresql"; DestName: pg_hba.conf.sample; Tasks: user ; Components: pgsql
Source: "pg_hba.conf.open"; DestDir: "{app}/usr/share/postgresql"; DestName: pg_hba.conf.sample; Tasks: open ; Components: pgsql
Source: "pg_hba.conf.closed"; DestDir: "{app}/usr/share/postgresql"; DestName: pg_hba.conf.sample; Tasks: closed ; Components: pgsql


[Icons]
Name: "{group}\PostgreSQL Server"; Filename: "{app}\bin\cygconsole.exe" ; WorkingDir: "{app}\bin"; Parameters: "PostgreSQL"; Components: pgsql ; Flags: runminimized;
Name: "{userstartup}\PostgreSQL Server"; Filename: "{app}\bin\cygconsole.exe" ; WorkingDir: "{app}\bin"; Parameters: "PostgreSQL"; Components: pgsql; Tasks: startmenu;
Name: "{group}\PSQL Samples"; Filename: "{app}\bin\pgsql.bat" ; WorkingDir: "{app}\bin"; Parameters: "{app}\bin samples"  ; Components: unix
Name: "{group}\PSQL Public"; Filename: "{app}\bin\pgsql.bat" ; WorkingDir: "{app}\bin"; Parameters: "{app}\bin public"  ; Components: unix
Name: "{group}\PostgreSQL System Console"; Filename: "{app}\bin\pgshell.bat" ; WorkingDir: "{app}\bin"; Parameters: "{app}\bin"  ; Components: unix;

[run]
Filename: "{app}\bin\cygconsole"; Description: "Creating Database Structure"; Parameters: "pgsetup"; Components: initdb

[Messages]
WelcomeLabel2=This program installs The PostgreSQL Server